git subrepo clone (merge) https://github.com/HarbourMasters/otrgui.git OTRGui

subrepo:
  subdir:   "OTRGui"
  merged:   "a6066a251"
upstream:
  origin:   "https://github.com/HarbourMasters/otrgui.git"
  branch:   "master"
  commit:   "a6066a251"
git-subrepo:
  version:  "0.4.1"
  origin:   "???"
  commit:   "???"

OTRGui/libs/raylib/examples/others/resources/shaders/glsl100/point_particle.fs

@@ -0,0 +1,16 @@
+#version 100
+
+precision mediump float;
+
+// Input uniform values
+uniform vec4 color;
+
+// NOTE: Add here your custom variables
+
+void main()
+{
+    // Each point is drawn as a screen space square of gl_PointSize size. gl_PointCoord contains where we are inside of
+    // it. (0, 0) is the top left, (1, 1) the bottom right corner.
+    // Draw each point as a colored circle with alpha 1.0 in the center and 0.0 at the outer edges.
+    gl_FragColor = vec4(color.rgb, color.a * (1.0 - length(gl_PointCoord.xy - vec2(0.5))*2.0));
+}

OTRGui/libs/raylib/examples/others/resources/shaders/glsl100/point_particle.vs

@@ -0,0 +1,24 @@
+#version 100
+
+// Input vertex attributes
+attribute vec3 vertexPosition;
+
+// Input uniform values
+uniform mat4 mvp;
+uniform float currentTime;
+
+// NOTE: Add here your custom variables
+
+void main()
+{
+    // Unpack data from vertexPosition
+    vec2  pos    = vertexPosition.xy;
+    float period = vertexPosition.z;
+
+    // Calculate final vertex position (jiggle it around a bit horizontally)
+    pos += vec2(100.0, 0.0) * sin(period * currentTime);
+    gl_Position = mvp * vec4(pos.x, pos.y, 0.0, 1.0);
+
+    // Calculate the screen space size of this particle (also vary it over time)
+    gl_PointSize = 10.0 - 5.0 * abs(sin(period * currentTime));
+}

OTRGui/libs/raylib/examples/others/resources/shaders/glsl330/point_particle.fs

@@ -0,0 +1,17 @@
+#version 330
+
+// Input uniform values
+uniform vec4 color;
+
+// Output fragment color
+out vec4 finalColor;
+
+// NOTE: Add here your custom variables
+
+void main()
+{
+    // Each point is drawn as a screen space square of gl_PointSize size. gl_PointCoord contains where we are inside of
+    // it. (0, 0) is the top left, (1, 1) the bottom right corner.
+    // Draw each point as a colored circle with alpha 1.0 in the center and 0.0 at the outer edges.
+    finalColor = vec4(color.rgb, color.a * (1 - length(gl_PointCoord.xy - vec2(0.5))*2));
+}

OTRGui/libs/raylib/examples/others/resources/shaders/glsl330/point_particle.vs

@@ -0,0 +1,24 @@
+#version 330
+
+// Input vertex attributes
+in vec3 vertexPosition;
+
+// Input uniform values
+uniform mat4 mvp;
+uniform float currentTime;
+
+// NOTE: Add here your custom variables
+
+void main()
+{
+    // Unpack data from vertexPosition
+    vec2  pos    = vertexPosition.xy;
+    float period = vertexPosition.z;
+
+    // Calculate final vertex position (jiggle it around a bit horizontally)
+    pos += vec2(100, 0) * sin(period * currentTime);
+    gl_Position = mvp * vec4(pos, 0.0, 1.0);
+
+    // Calculate the screen space size of this particle (also vary it over time)
+    gl_PointSize = 10 - 5 * abs(sin(period * currentTime));
+}

OTRGui/libs/raylib/examples/others/resources/shaders/glsl430/gol.glsl

@@ -0,0 +1,41 @@
+#version 430
+
+// Game of Life logic shader
+
+#define GOL_WIDTH 768
+
+layout (local_size_x = 16, local_size_y = 16, local_size_z = 1) in;
+
+layout(std430, binding = 1) readonly restrict buffer golLayout {
+    uint golBuffer[];       // golBuffer[x, y] = golBuffer[x + gl_NumWorkGroups.x * y]
+};
+
+layout(std430, binding = 2) writeonly restrict buffer golLayout2 {
+    uint golBufferDest[];   // golBufferDest[x, y] = golBufferDest[x + gl_NumWorkGroups.x * y]
+};
+
+#define fetchGol(x, y) ((((x) < 0) || ((y) < 0) || ((x) > GOL_WIDTH) || ((y) > GOL_WIDTH)) \
+    ? (0) \
+    : golBuffer[(x) + GOL_WIDTH * (y)])
+
+#define setGol(x, y, value) golBufferDest[(x) + GOL_WIDTH*(y)] = value
+
+void main()
+{
+    uint neighbourCount = 0;
+    uint x = gl_GlobalInvocationID.x;
+    uint y = gl_GlobalInvocationID.y;
+
+    neighbourCount += fetchGol(x - 1, y - 1);   // Top left
+    neighbourCount += fetchGol(x, y - 1);       // Top middle
+    neighbourCount += fetchGol(x + 1, y - 1);   // Top right
+    neighbourCount += fetchGol(x - 1, y);       // Left
+    neighbourCount += fetchGol(x + 1, y);       // Right
+    neighbourCount += fetchGol(x - 1, y + 1);   // Bottom left
+    neighbourCount += fetchGol(x, y + 1);       // Bottom middle   
+    neighbourCount += fetchGol(x + 1, y + 1);   // Bottom right
+
+    if (neighbourCount == 3) setGol(x, y, 1);
+    else if (neighbourCount == 2) setGol(x, y, fetchGol(x, y));
+    else setGol(x, y, 0);
+}

OTRGui/libs/raylib/examples/others/resources/shaders/glsl430/gol_render.glsl

@@ -0,0 +1,29 @@
+#version 430
+
+// Game of Life rendering shader
+// Just renders the content of the ssbo at binding 1 to screen
+
+#define GOL_WIDTH 768
+
+// Input vertex attributes (from vertex shader)
+in vec2 fragTexCoord;
+
+// Output fragment color
+out vec4 finalColor;
+
+// Input game of life grid.
+layout(std430, binding = 1) readonly buffer golLayout
+{
+    uint golBuffer[];
+};
+
+// Output resolution
+uniform vec2 resolution;
+
+void main()
+{
+    ivec2 coords = ivec2(fragTexCoord*resolution);
+
+    if ((golBuffer[coords.x + coords.y*uvec2(resolution).x]) == 1) finalColor = vec4(1.0);
+    else finalColor = vec4(0.0, 0.0, 0.0, 1.0);
+}

OTRGui/libs/raylib/examples/others/resources/shaders/glsl430/gol_transfert.glsl

@@ -0,0 +1,51 @@
+#version 430
+
+// Game of life transfert shader
+
+#define GOL_WIDTH 768
+
+// Game Of Life Update Command
+// NOTE: matches the structure defined on main program
+struct GolUpdateCmd {
+    uint x;         // x coordinate of the gol command
+    uint y;         // y coordinate of the gol command
+    uint w;         // width of the filled zone
+    uint enabled;   // whether to enable or disable zone
+};
+
+// Local compute unit size
+layout (local_size_x = 1, local_size_y = 1, local_size_z = 1) in;
+
+// Output game of life grid buffer
+layout(std430, binding = 1) buffer golBufferLayout
+{
+    uint golBuffer[]; // golBuffer[x, y] = golBuffer[x + GOL_WIDTH * y]
+};
+
+// Command buffer
+layout(std430, binding = 3) readonly restrict buffer golUpdateLayout
+{
+    uint count;
+    GolUpdateCmd commands[];
+};
+
+#define isInside(x, y) (((x) >= 0) && ((y) >= 0) && ((x) < GOL_WIDTH) && ((y) < GOL_WIDTH))
+#define getBufferIndex(x, y) ((x) + GOL_WIDTH * (y))
+
+void main()
+{
+    uint cmdIndex = gl_GlobalInvocationID.x;
+    GolUpdateCmd cmd = commands[cmdIndex];
+
+    for (uint x = cmd.x; x < (cmd.x + cmd.w); x++)
+    {
+        for (uint y = cmd.y; y < (cmd.y + cmd.w); y++)
+        {
+            if (isInside(x, y))
+            {
+                if (cmd.enabled != 0) atomicOr(golBuffer[getBufferIndex(x, y)], 1);
+                else atomicAnd(golBuffer[getBufferIndex(x, y)], 0);
+            }
+        }
+    }
+}